***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*May 14, 2019                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJQ4446P   D   G   S
*****param & model definition***
.model  dmos  nmos(
+    l = 1e-6		  w = 1e-6			level = 3
+  vto = 2.2		 kp = 40)
.model  dds   d(
+   is = 3.043e-12	  n = 1.025			   rs = 6.645e-3
+   eg = 1.122	     trs1 = 5.188e-3)
.model  dbody d(
+   is = 3.043e-12	  n = 1.025			   rs = 6.645e-3
+  cjo = 3.419e-10	  m = 4.421e-1		   vj = 2.927e-1
+   bv = 44			ibv = 250e-6		 tbv1 = 9.644e-4			tt = 25n)
.model  inter  nmos(
+  vto = 0			 kp = 10			level = 1)
.model  dgd   d(
+  cjo = 4.445e-10	  m = 3.731e-1		   vj = 3.352e-1)
.param
+  cgs = 1.612e-9		cgd = 4.004e-10
+   rd = 3.855e-4		 ra = 4.885e-4		  trd = 8.045e-2
*****function & circuit***
rg	  G  1t   1
cgs	 1t   3   {cgs}    ic = 0
egv	 2t   3   table   {v(1t, S)} 
+((0.00 , 0.00 ),
+ (0.50 , 0.50 ), 
+ (1.00 , 1.00 ),
+ (1.50 , 1.50 ),
+ (2.00 , 2.20 ),
+ (2.50 , 2.70 ),
+ (3.00 , 3.30 ),
+ (3.50 , 3.80 ),
+ (4.00 , 4.30 ),
+ (4.50 , 4.80 ),
+ (5.00 , 5.10 ),
+ (6.00 , 5.40 ),
+ (8.00 , 5.80 ),
+ (10.0 , 6.00 ),   
+ (20.0 , 7.00 ),
+ (22.0 , 7.00 ))
egt	  1  2t   value = {1.187e-3*limit(v(2t,3),0,5)*limit((temp-25),-80,125)}
mmain	  2   1   3   3   dmos
rd	  D   4   {rd}    tc = {trd}
dds	  3   4   dds
dbody	  3   D   dbody
ra	  4   2   {ra} 
rs	  3   5   1e-4
ls	  5   S   0.001n 
m1     1t   8   6   6   inter
e1      8   6   4  1t   2
cgd	  7   4   {cgd}   ic = 0
rcgd    7   4   10meg
dgd     6   4   dgd
rdgd    4   6   10meg
m2      7   9  1t  1t   inter
e2      9  1t   4  1t   -2
.ends 
*$
